====== Пример встраивания панели телефонии. ======

Панель телефонии может работать в безинтеграцонном режиме. В этом разделе будут описаны достоинства и недостатки данного режима работы. Кроме того, будет описан способ интеграции панели на примере конфигурации  УТ 10.3, что позволит использовать функционал панели в полной мере.

<note important>Инструкция применима к панели телефонии версии 1.*.19. [[doc:panel1cut:config_bezint?rev=1364633919|Инструкция для прошлых версий.]]</note>

===== Достоинства безинтеграционного режима работы: =====

  * Не требуется изменение конфигурации. Панель может быть запущена через главное меню **“Файл -Открыть”**. При этом доступен практически весь функционал панели.
===== Особенности и ограничения: =====

  * Для определения контрагента по номеру телефона используется временная таблица контактной информации, эта таблица обновляется с периодичностью, указанной в настройках панели. Врменная таблица - своего рода кэш контактной информации.
  * При формировании докумнта “Событие” средстави панели телефонии не сохраняется связка звонка и события, т.е. каждый раз будет создаваться новый документ “Событие”.
  * Нет возможности набирать номер телефона контрагента из его карточки.
  * Нет возможности отправки факса в текущий разговор средствами стандартной общей формы печати.
  * Пользователю необходим расширенный набор прав: разрешить открытие внешних обработок.

===== Пример интеграции в **УТ 10.3.17.4**.=====
Далее будет описан пример интеграции панели, в котором будет предложен вариант преодоления ограничений. 

<note important>Обязательно перед началом работ выполняйте резервное копирование информационной базы!</note>

Для начала необходимо открыть информационную базу в режиме запуска «Конфигуратор». Для объектов следует установить правило поддержки «Редактируется с сохранением поддержки».

[[doc:panel1cbp20:config_bezint_gibrid_podderjka|Настройка поддержки]]

------------------------------------------------------------------------------------------------
**Задача:** Необходимо открывать форму панели телефонии автоматически при старте 1С.

**Решение:** 
  - Добавим в дерево метаданных обработку **"МИКО_ПанельТелефонииAsterisk"**
  - Добавим в дерево метаданных новую роль: 
    * Имя     **"МИКО_ИспользованиеСофтфона"**. 
    * Синоним **"Использование панели телефонии  Asterisk (МИКО)"**. 
Установить права на чтение и использование обработки "МИКО_ПанельТелефонииAsterisk".
  - Модифицировать модуль обычного приложения
Раздел определения переменных:
<code 1c>Перем глОбщиеЗначения Экспорт;
// {{{ Панель телефонии Asterisk, МИКО }}} НАЧАЛО
Перем Miko_Ajam Экспорт;// МИКО обработка управления звонками
// {{{ Панель телефонии Asterisk, МИКО }}} КОНЕЦ
Перем глЗапрашиватьПодтверждениеПриЗакрытии Экспорт;
</code>

Процедуры - обработчики событий:

<code 1c>Процедура ПриНачалеРаботыСистемы()
	
	// ... ... ... Внимание!!! Пропущена часть кода!!! ... ... ...
	
	// Открытие формы помощника обновления конфигурации
	Если РольДоступна(Метаданные.Роли.ПолныеПрава) Тогда
		ОбработкаОбновлениеКонфигурации = Обработки.ОбновлениеКонфигурации.Создать();
		ОбработкаОбновлениеКонфигурации.ПроверитьНаличиеОбновлений();
	КонецЕсли;
	
	// {{{ Панель телефонии Asterisk, МИКО }}} НАЧАЛО
	// установка глобадьных переменных
	Если РольДоступна("ПолныеПрава")
		 ИЛИ РольДоступна("МИКО_ИспользованиеСофтфона") Тогда
		Попытка
			Miko_Ajam = Обработки.МИКО_ПанельТелефонииДля1С.Создать();
			Miko_Ajam.ПодключитьСофтФон();
		Исключение
			Сообщить("Ошибка подключения СофтФона (МИКО):", СтатусСообщения.ОченьВажное);
			Сообщить(ОписаниеОшибки());
		КонецПопытки; 
	КонецЕсли; 
	// {{{ Панель телефонии Asterisk, МИКО }}} КОНЕЦ
	
КонецПроцедуры // ПриНачалеРаботыСистемы()
</code>

<code 1c>
Процедура ОбработкаВнешнегоСобытия(Источник, Событие, Данные)

	Если мКлиентOnline <> Неопределено Тогда
		мКлиентOnline.ВнешнееСобытие(Источник, Событие, Данные);
	КонецЕсли;

	ПолучитьСерверТО().ЗавершитьОбработкуВнешнегоСобытия(Источник, Событие, Данные);
	// {{{ Панель телефонии Asterisk, МИКО }}} НАЧАЛО
	Если НЕ Miko_Ajam  = Неопределено
		И (Источник = "MikoAjamEvent" ИЛИ Источник = "MIKO_SoftPhone" ИЛИ Источник = "MIKO_InFormAutor") Тогда

		Miko_Ajam.ОбработкаВнешнегоСобытияАстериск(Источник, Событие, Данные);
	КонецЕсли; 
	// {{{ Панель телефонии Asterisk, МИКО }}} КОНЕЦ
КонецПроцедуры // ОбработкаВнешнегоСобытия()
</code>

<code 1c>Процедура ПередЗавершениемРаботыСистемы(Отказ)
	
	// ... ... ... Внимание!!! Пропущена часть кода!!! ... ... ...
	
	Если НЕ Отказ Тогда
		
		// отдельно получаем настройки для которых нужно выполнить обмен при выходе из программы
		ПроцедурыОбменаДанными.ВыполнитьОбменПриЗавершенииРаботыПрограммы(глЗначениеПеременной("глОбработкаАвтоОбменДанными"));
			
	КонецЕсли;

	// {{{ МИКО }}} НАЧАЛО Панель телефонии Asterisk
	// Завершим работу Панель телефонии Asterisk перед выходом из предприятия
	Если НЕ Отказ И НЕ Miko_Ajam  = Неопределено Тогда
		Miko_Ajam.ОтключитьВК();
	КонецЕсли;
	// {{{ МИКО }}} КОНЕЦ Панель телефонии Asterisk
КонецПроцедуры
</code>
==== Документ "Событие" ====

------------------------------------------------------------------------------------------------
**Задача:** необходимо хранить связку документа события с записью в истории звонков. При открытии документа события из истории, должен открываться документ сформированный ранее по этой записи.

**Решение:** для документа "Событие" необходимо добавить новый реквизит:
  * Имя = "**CRM_GUIDЗвонка**" 
  * Тип = **фиксированная строка 38** символов
------------------------------------------------------------------------------------------------

**Задача:** необходимо добавить возможность прослушать запись разговора, связанного с документом "Событие", из формы документа. Кроме того необходимо добавить возможность набрать номер контрагента, либо его контактного лица из формы документа.

**Решение:** необходимо модифицировать модуль формы документа:
<code 1c>// Обработчик события ПриОткрытии формы.
//
Процедура ПриОткрытии()
    
    // ... ... ... 
	
	мПоследнееЗначениеЭлементаПоискаПоСтрокеКонтрагент     = Контрагент;
	мПоследнееЗначениеЭлементаПоискаПоСтрокеКонтактноеЛицо = КонтактноеЛицо;
	мТекущаяДатаДокумента                                  = Дата;
	// {{{ МИКО Панель телефонии Asterisk }}} НАЧАЛО
	Если НЕ Miko_Ajam = Неопределено
		 И  НЕ Miko_Ajam.мОбщийМодуль = Неопределено Тогда
		мОбщийМодуль = Miko_Ajam.мОбщийМодуль;
		// добавляем кнопку вызова
		мОбщийМодуль.ДобавитьКнопкуЗвонкаНаПанельДействий(ЭлементыФормы.ДействияФормы.Кнопки,
														  "МИКО_ВыполнитьДействие", 
                                                          "кнМИКО_НабратьНомерВыбравИзСписка");
		// добавляем кнопку прослушивания записи разговора
		мОбщийМодуль.ДобавитьКнопкуПрослушиванияЗаписиНаПанельДействий(ЭлементыФормы.ДействияФормы.Кнопки,
                                                                       "МИКО_ВыполнитьДействие", 
                                                                       "кнМИКО_ПрослушатьЗапись");
	КонецЕсли; 
	// {{{ МИКО Панель телефонии Asterisk }}} КОНЕЦ	
	Модифицированность = Ложь;

КонецПроцедуры  // ПриОткрытии()</code>

добавить в форму обработчик нажатия кнопок:
<code 1c>
// МИКО // Набор номера по заданному алгоритму
// 
Процедура МИКО_ВыполнитьДействие(Кнопка)
 	Действие = Кнопка.Имя;
	Если Miko_Ajam = Неопределено Тогда Возврат; КонецЕсли;
	
	Если Действие = "кнМИКО_НабратьНомерВыбравИзСписка" Тогда
		// Позвонить по телефону выбранному пользователем из списка, определенных у контрагента и контактного лица
		СписокОбъектов = Новый Структура();
		СписокОбъектов.Вставить("Контрагент", Контрагент);
		СписокОбъектов.Вставить("КонтактноеЛицо", КонтактноеЛицо);
		// Данные незарегистрированных контрагентов:
		СписокОбъектов.Вставить("Событие", Ссылка);
 
		Miko_Ajam.ПозвонитьВыбравТелефон(СписокОбъектов);
	ИначеЕсли Действие = "кнМИКО_ПрослушатьЗапись" Тогда
		Если НЕ ЗначениеЗаполнено(CRM_GUIDЗвонка) Тогда
			Сообщить("К событию не прикреплено записи разговора!");
			Возврат;
		КонецЕсли;
		// Прослушать запись разговора, прикрепленного к событию
		Miko_Ajam.ПрослушатьЗаписьРазговора(CRM_GUIDЗвонка);
	КонецЕсли;	
КонецПроцедуры
</code>
Документ при открытии будет выглядеть следующим образом:

{{ :doc:panel1cut:dokument_sobytie.jpg? |}}
==== Контактная информация ====

------------------------------------------------------------------------------------------------
**Задача:** необходимо, для поиска номеров в базе использовать запрос не по временной таблице, а непосредственно по регистру сведений "КонтактнаяИнформация". 

**Решение:** необходимо модифицировать регистр сведений **"КонтактнаяИнформация"**:
Добавить ресурсы:
  * "**CRM_ПолеХраненияНомера**" (число длина 32)
  * "**CRM_НомерТелефона**" (переменная строка 32)

В модуле набора записей изменить процедуру:

<code 1c>
Процедура ПередЗаписью(Отказ, Замещение)
	Если ОбменДанными.Загрузка Тогда
		Возврат;
	КонецЕсли;

	Для каждого Запись Из ЭтотОбъект Цикл
		Если НЕ ЗначениеЗаполнено(Запись.Объект) Тогда
			Отказ = Истина;
			СтрокаОтказа = "Не заполнен объект.";
			Продолжить;
		КонецЕсли; 
		Если Запись.Объект.ЭтоГруппа Тогда
			Отказ = Истина;
			СтрокаОтказа = "Нельзя использовать в качестве объекта контактной информации - группу.";
			Прервать;
		КонецЕсли;
		#Если Клиент Тогда 
		//{{{ МИКО }}} НАЧАЛО Код встраивания "Панель телефонии Asterisk"
		Если НЕ Miko_Ajam = Неопределено                       
                     И НЕ Miko_Ajam.мОбработкаДанных = Неопределено
                     И Запись.Тип = Перечисления.ТипыКонтактнойИнформации.Телефон Тогда
			ПредставлениеНомера = Запись.Поле1 + Запись.Поле2 + Запись.Поле3;
 
			Если ЗначениеЗаполнено(Запись.Поле4) И НЕ ЗначениеЗаполнено(ПредставлениеНомера) Тогда
				Запись.CRM_ПолеХраненияНомера = Miko_Ajam.мОбработкаДанных.ПреобразоватьНомерДляСохранения(Запись.Поле4,  Miko_Ajam.ГлобальныеПеременные.глКоличествоХранимыхЦифрТелефона);
				Запись.CRM_НомерТелефона      = Miko_Ajam.мОбработкаДанных.УбратьИзНомераТелефонаВсеБуквы   (Запись.Поле4);
			Иначе
				Запись.CRM_ПолеХраненияНомера = Miko_Ajam.мОбработкаДанных.ПреобразоватьНомерДляСохранения (ПредставлениеНомера,  Miko_Ajam.ГлобальныеПеременные.глКоличествоХранимыхЦифрТелефона);
				Запись.CRM_НомерТелефона      = Miko_Ajam.мОбработкаДанных.УбратьИзНомераТелефонаВсеБуквы    (ПредставлениеНомера);
			КонецЕсли;
		КонецЕсли;
		
		// Для возможности сохранения Скайп номера
		Если Найти(Запись.Вид,"Skype")>0 Тогда
			Запись.CRM_НомерТелефона = Запись.Представление;
		Иначе
			Запись.Представление	= Miko_Ajam.мОбработкаДанных.СформироватьСтруктуруНомераИзПолей(Запись).Представление;
		КонецЕсли;
		//{{{ МИКО }}} КОНЕЦ

		#конецесли
	КонецЦикла;
		
	Если Отказ Тогда
		Сообщить(СтрокаОтказа);
	КонецЕсли; 
	
КонецПроцедуры
</code>

После этого, добавленные ранее ресурсы, будут заполняться надлежащим образом.
==== Справочник "Контрагенты" ====

------------------------------------------------------------------------------------------------
**Задача:** необходимо, добавить возможность произвести звонок из карточки контрагента. 

**Решение:** необходимо модифицировать форму элемента справочника "Контрагенты":
<code 1c>
// Обработчик события ПриОткрытии формы.
//
Процедура ПриОткрытии()

	// ... ... ... Внимание!!! Отсутствует часть исходного кода!!!
	
	// Установить печатную форму по умолчанию.
	РаботаСДиалогами.УстановитьКнопкуПечати(ЭтотОбъект, ЭтаФорма);
	// {{{ МИКО Панель телефонии Asterisk }}} НАЧАЛО
	Если НЕ Miko_Ajam = Неопределено 
		 И НЕ Miko_Ajam.мОбщийМодуль = Неопределено Тогда
		мОбщийМодуль = Miko_Ajam.мОбщийМодуль;
		// добавляем элементы управления на форму
 
		мОбщийМодуль.ДобавитьКнопкуЗвонкаНаПанельДействий(ЭлементыФормы.ДействияФормы.Кнопки,
                                                          "МИКО_ВыполнитьДействие", 
                                                          "кнМИКО_НабратьНомерВыбравИзСписка");
		мОбщийМодуль.ДобавитьКнопкуЗвонкаНаПанельДействий(ЭлементыФормы.КоманднаяПанельКонтактнаяИнформация.Кнопки,
                                                          "МИКО_ВыполнитьДействие",
                                                          "кнМИКО_НабратьНомерИзКИ");
		мОбщийМодуль.ДобавитьКнопкуЗвонкаНаПанельДействий(ЭлементыФормы.КоманднаяПанельКонтактныеЛицаКонтрагента.Кнопки,
                                                          "МИКО_ВыполнитьДействие", 
                                                          "кнМИКО_НабратьНомерВыбравКЛ");
	КонецЕсли; 
	// {{{ МИКО Панель телефонии Asterisk }}} КОНЕЦ	
КонецПроцедуры
</code>

добавить обработчик нажатия кнопок:

<code 1c>
// МИКО // Набор номера по заданному алгоритму
// 
Процедура МИКО_ВыполнитьДействие(Кнопка)
 	Действие = Кнопка.Имя;
	Если Miko_Ajam = Неопределено Тогда Возврат; КонецЕсли;
 
	Если Действие = "кнМИКО_НабратьНомерИзКИ" Тогда
		// Позвонить по выбранному контакту 
		ТекущаяСтрока = ЭлементыФормы.КонтактнаяИнформация.ТекущиеДанные;
		Если НЕ ТекущаяСтрока = Неопределено Тогда
			Miko_Ajam.НабратьНомерКИ(ЭлементыФормы.КонтактнаяИнформация.ТекущиеДанные);
		КонецЕсли; 
	ИначеЕсли Действие = "кнМИКО_НабратьНомерВыбравИзСписка"  ТОгда
		// Позвонить по телефону, выбранному пользователем из списка телефонов определенных у контрагента и контактного лица
		СписокОбъектов = Новый Структура();
		СписокОбъектов.Вставить("Контрагент", Ссылка);
		СписокОбъектов.Вставить("КонтактноеЛицо", ОсновноеКонтактноеЛицо);
		Если НЕ Ссылка = ГоловнойКонтрагент Тогда
			СписокОбъектов.Вставить("КонтактноеЛицо", ГоловнойКонтрагент);
		КонецЕсли; 
 
		Miko_Ajam.ПозвонитьВыбравТелефон(СписокОбъектов);
	ИначеЕсли Действие = "кнМИКО_НабратьНомерВыбравКЛ" Тогда	
		// Позовонить выбранному контактному лицу
		ТекущиеДанные = ЭлементыФормы.КонтактныеЛицаКонтрагента.ТекущиеДанные;
		Если НЕ ТекущиеДанные = Неопределено Тогда
			СписокОбъектов = Новый Структура();
			СписокОбъектов.Вставить("КонтактноеЛицо", ТекущиеДанные.Ссылка);
			Miko_Ajam.ПозвонитьВыбравТелефон(СписокОбъектов);
		КонецЕсли;
	ИначеЕсли Действие = "УстановитьДоступностьКнопокСофтфона" Тогда	
		Miko_Ajam.мОбщийМодуль.УстановитьДоступностьКнопокСофтфона(ЭлементыФормы.КонтактнаяИнформация.ТекущиеДанные,
                                                                              ЭлементыФормы.КоманднаяПанельКонтактнаяИнформация.Кнопки,
								              "кнМИКО_НабратьНомерИзКИ");
	КонецЕсли; 
 
КонецПроцедуры
</code>

Кнопки должны быть доступны только для контактной информации с типом "Телефон"
<code 1c>
// Обработчик события ПриАктивизацииСтроки элемента формы КонтактнаяИнформация.
//
Процедура КонтактнаяИнформацияПриАктивизацииСтроки(Элемент)
	
	УправлениеКонтактнойИнформацией.КонтактнаяИнформацияПриАктивизацииСтрокиТаблицы(Элемент, ЭлементыФормы.КоманднаяПанельКонтактнаяИнформация.Кнопки.УстановитьОсновным);
	// {{{ МИКО Панель телефонии Asterisk }}} НАЧАЛО
	Если НЕ Miko_Ajam = Неопределено
		 И  НЕ Miko_Ajam.мОбщийМодуль = Неопределено Тогда
		МИКО_ВыполнитьДействие(Новый Структура("Имя","УстановитьДоступностьКнопокСофтфона"));
	КонецЕсли;
	// {{{ МИКО Панель телефонии Asterisk }}} КОНЕЦ	
КонецПроцедуры
</code>

Форма элемента справочника примет следующий вид:
{{ :doc:panel1cut:forma_kontragenta.png? |}}
==== Общая форма печати документов ====
**Задача:** необходимо, добавить возможность отправки сформированной печатной формы в виде факсимильного сообщения в текущий вызов.

**Решение:** необходимо модифицировать общую форму "ПечатьДокументов":

<code 1c>
Процедура ПриОткрытии()
	
	ЭлементыФормы.ПолеТабличногоДокумента.ВставитьОбласть(ПечатныйДокумент.Область());
	
	ЭлементыФормы.ПолеТабличногоДокумента.ОтображатьЗаголовки = Ложь;
	ЭлементыФормы.ПолеТабличногоДокумента.ОтображатьСетку     = Ложь;
	ЭлементыФормы.ПолеТабличногоДокумента.Защита              = Защита;
	ЭлементыФормы.ПолеТабличногоДокумента.ТолькоПросмотр      = Истина;
	ЭлементыФормы.ПолеТабличногоДокумента.ИмяПараметровПечати = ПечатныйДокумент.ИмяПараметровПечати;
	ЭлементыФормы.ПолеТабличногоДокумента.ПовторятьПриПечатиСтроки = ПечатныйДокумент.ПовторятьПриПечатиСтроки;
	// {{{ МИКО Панель телефонии Asterisk }}} НАЧАЛО
	Если НЕ Miko_Ajam = Неопределено 
		И НЕ Miko_Ajam.мОбщийМодуль = Неопределено Тогда
		мОбщийМодуль = Miko_Ajam.мОбщийМодуль;
		// добавляем элементы управления на форму
		мОбщийМодуль.ДобавитьКнопкуОтправкиФаксаНаПанельДействий(ЭлементыФормы.КоманднаяПанельФормы.Кнопки, 
                                                                          "МИКО_ВыполнитьДействие", 
                                                                          "кнМИКО_ОтправитьФакс");
	КонецЕсли; 
	// {{{ МИКО Панель телефонии Asterisk }}} КОНЕЦ	
КонецПроцедуры
</code>

добавить обработчик нажатия кнопки:

<code 1c>
// Набор номера по заданному алгоритму
//
Процедура МИКО_ВыполнитьДействие(Кнопка)
 	Действие = Кнопка.Имя;
	Если Miko_Ajam = Неопределено Тогда Возврат; КонецЕсли;
 
	Если Действие = "кнМИКО_ОтправитьФакс" Тогда
		// Обработчик нажатия на кнопку отправки табличного документа в текущий разговор
		Miko_Ajam.ОтправитьФаксомТабДок(ЭлементыФормы.ПолеТабличногоДокумента);
	КонецЕсли; 
 
КонецПроцедуры
</code>

Общая печатная форма примет вид:
{{ :doc:panel1cut:obschaja_forma_pechati_dokumentov.png? |}}